function get_gatlin_rainrate,dbz,zdr,kdp,rhv,hid,method,MISSING=missing
;+
; Function that accepts DP radar parameters and returns the respective
; rain rate (and method) using the simulations run by Patrick Gatlin
; using disdrometer data
;
; *** Check to see if the HID is ice species or liquid species.
; *** If ice, then do not calculate RR at this bin.
; *** -1: Bad Data
; ***  0: Unclassified  [UC]
; ***  1: Drizzle       [DZ]
; ***  2: Rain          [RN]
; ***  3: Ice Crystals  [CR]
; ***  4: Dry Snow      [DS]
; ***  5: Wet Snow      [WS]
; ***  6: Vertical Ice  [VI]
; ***  7: Low Den Graup [LDG]
; ***  8: Hi Den Graup  [HDG]
; ***  9: Hail          [HA]
; *** 10: Big Drops     [BD]
      
    if(NOT KEYWORD_SET(MISSING)) then missing=-32768.0
    rrg = missing
    method = missing

    zlin = 10D^(0.1*dbz)
    
    if(dbz gt -4 and dbz le 53.6) then begin
       rrg = 0.0278 * (zlin^0.636)
       method = 1
       if(zdr gt 0 and zdr le 2.2) then begin
          rrg = 0.0049 * (zlin^0.98) * 10D^(0.42 * zdr)
          method = 2
       endif
    endif
    
    if(kdp gt 0 and kdp le 2.39) then begin
       rrg = 45.4 * (Kdp^0.82)
       method = 3
       if(zdr gt 0 and zdr le 2.2) then begin
          rrg = 141D * (kdp^0.99) * 10D^(-0.22 * zdr)
          method = 4
       endif
    endif
    
    return,rrg
    end