function get_thurai_rainrate,dbz,zdr,kdp,method,rhv,hid,MISSING=missing
;
; *** Function that accepts a dbz, zdr and kdp value and then
; *** returns a rain rate value.  This follows the algorithm
; *** provided by Thurai et al. MC3E Poster AGU 2012.
;
    if(NOT KEYWORD_SET(MISSING)) then missing=-999.99
    if(dbz eq missing) then begin
        r = missing
        return,r
    endif
    
    Zh_lin = 10D^(0.1 * dbz)
    Zdr_lin = 10D^(0.1 * zdr)
;
; *** Default is to use Zh_lin only
;
    method = 1
    Rtest = 0.0229D * (Zh_lin^0.6425D)
;
; *** Follow logic tree to determine which method to use.
;
    if(Rtest gt 6) then begin
;
; *** Yes
;        
        if(kdp gt 0.5) then begin
            method = 2
        endif else begin
            if(zdr gt 0.25) then begin
                method = 3
            endif else begin
                method = 1
            endelse
        endelse

    endif else begin
;
; *** No
;        
        if(zdr gt 0.25) then begin
            method = 3
        endif else begin
            method = 1
        endelse
        
    endelse
;
; *** Calculate R based on selected method
;    
    CASE method of
        1: BEGIN
            R = Rtest
        END
        2: BEGIN
            R = 34.3D*(kdp^0.757D)
        END
        3: BEGIN
            R = 0.0142D * (Zh_lin^0.77D / Zdr_lin^1.67D)
        END
    ENDCASE

    return,r
    end